remarks sa_l.inp   
remarks Author: Michael Nilges, Jens Linge 26.8.98

!initialize some variables:
evaluate ($spectrum = "")
evaluate ($shifts   = "")
evaluate ($restraintfile = "")
evaluate ($listfile = "")

!for the ARIA iterations:
evaluate ($iteration=1) 

!some information for your run:
{* sa_protocol *}
evaluate ($iniseed = 89764443)
evaluate ($init_t = 9000)
evaluate ($final1_t = 1000)
evaluate ($final2_t = 50)
evaluate ($tempstep = 50)
evaluate ($tadfactor = 9)
evaluate ($InitioSteps = 2000)
evaluate ($RefineSteps = 500)
evaluate ($cool1_Steps = 1000)
evaluate ($cool2_Steps = 1000)
evaluate ($fbeta = 20)
evaluate ($mass = 100)

{* fileNames *}
{===>} evaluate ($fileroot =  "test")
{===>} evaluate ($reference = "testreference.pdb")
{===>} evaluate ($template =  "testtemplate.pdb")
{===>} evaluate ($structure = "testpsf.psf")
evaluate ($flags = "flags_tad.xplor")

{* iterations *}
evaluate ($DistCutoff = 100.0)

if ($iteration = 1) then
    evaluate ($Ini_count = 1)
    evaluate ($AmbigCutoff = 0.9999)
    evaluate ($ViolToler = 5.0)
    evaluate ($AssignStruct = 30)
    evaluate ($ViolRatio = 0.5)
    evaluate ($Structures = 30)
    evaluate ($keepStruct = 0)
end if

topology  
    @@topallhdg.pro
    @@topallhdg.sol
end 

evaluate ($par_nonbonded = "OPLSX")    !for the water refinement
parameter 
  @@parallhdg5.0.pro
  @@parallhdg.sol
  nbonds
    nbxmod=5 atom cdiel shift 
    cutnb=9.5 ctofnb=8.5 ctonnb=6.5 eps=1.0 e14fac=0.4 inhibit 0.25
    wmin=0.5
    tolerance  0.5
  end
end



!parameter  nbfix S  S  462  13.6  462  13.6 end
{
parameter
   bond (name sg) (name sg) 0.0 TOKEN
   angle (all) (name sg) (name sg)  0.0 TOKEN
end
}


evaluate ($kcdih = 5)
restraints dihedral 
      scale=$kcdih                      {* initial weight - will be modified later *}
end 


evaluate ($count = 0)
for $file in ( @@file.list )  loop main
   evaluate ($count = $count + 1)
   evaluate ($seed = ($count+1)*$iniseed)
   set seed $seed end

   evaluate ($cpu1 = $cpu)

   evaluate ($ncycle = ($init_t-$final1_t)/$tempstep)
   evaluate ($nstep = int($cool1_steps/$ncycle))

   @h2orefinenew2.xplor

   evaluate ($filename=$file - ".pdb" + "w.pdb")

   evaluate ($impr = 0)
   print threshold=0.5 noe 
   evaluate ($rms_noe=$result)
   evaluate ($violations_noe=$violations)
   print threshold=5. cdih
   evaluate ($rms_cdih=$result)
   evaluate ($violations_cdih=$violations)
   print thres=0.05 bonds          
   evaluate ($rms_bonds=$result)
   print thres=5. angles
   evaluate ($rms_angles=$result)
   print thres=5. impropers
   evaluate ($rms_impropers=$result)
   coor disp=comp @@$reference
   coor sele=(name ca) fit end coor sele= (name ca) rms end
   evaluate ($rmsxray = $result)
   remarks initial random number seed: $seed
   remarks rmsdifference $rmsxray
   remarks =============================================================== 
   remarks            overall,bonds,angles,improper,vdw,noe,cdih
   remarks energies: $ener, $bond, $angl, $impr, $vdw, $noe, $cdih 
   remarks =============================================================== 
   remarks            bonds,angles,impropers,noe,cdih
   remarks rms-dev.: $rms_bonds,$rms_angles,$rms_impropers,$rms_noe,$rms_cdih
   remarks =============================================================== 
   remarks               noe,  cdih
   remarks violations.: $violations_noe, $violations_cdih
   remarks =============================================================== 

   vector do (q=1) (all)
   write coordinates sele= (not resn TIP3) output =$filename end
      
end loop main

stop