REMARK Author: Michael Nilges
REMARK Ref: Nilges, M. (1993), A calculation strategy for the structure
REMARK      determination of symmetric dimers by 1H NMR.
REMARK      Proteins 17, 297-309.
REMARK
REMARK setup symmetry distance restraints, for a trimer
REMARK disclaimer: this file was never tested

@psf_bld_monomer.inp
duplicate selection= (segid A) segid = B end 
duplicate selection= (segid A) segid = C end 

set display symmetry.tbl end

! get number of residues in monomer
vector do (store1 = decode(resid)) (segid a and name ca)
vector show min (store1) (segid a and name ca)
evaluate ($first_residue = $result)
vector show max (store1) (segid a and name ca)
evaluate ($last_residue = $result)

for $id in id (name ca and segid a) loop res1
    vector show element (resid) (id $id)
    evaluate ($resid1 = decode($result))
    evaluate ($resid2 = $last_residue - $resid1 + $first_residue)
    if ($resid2 > $resid1) then
        display ! distance pair $resid1 $resid2
        display assign (resid $resid1 and name ca and segid a)
        display        (resid $resid2 and name ca and segid b) 0.0 0.0 0.0
        display assign (resid $resid1 and name ca and segid b)
        display        (resid $resid2 and name ca and segid c) 0.0 0.0 0.0
        display
        display assign (resid $resid1 and name ca and segid b)
        display        (resid $resid2 and name ca and segid c) 0.0 0.0 0.0
        display assign (resid $resid1 and name ca and segid c)
        display        (resid $resid2 and name ca and segid a) 0.0 0.0 0.0
        display
        display assign (resid $resid1 and name ca and segid c)
        display        (resid $resid2 and name ca and segid a) 0.0 0.0 0.0
        display assign (resid $resid1 and name ca and segid a)
        display        (resid $resid2 and name ca and segid b) 0.0 0.0 0.0
        display

    end if
end loop res1
                                 
stop